SCREENSET

FreeBASIC-Referenz » Alphabetische Befehlsreferenz » S » SCREENSET

Syntax: SCREENSET [aktive_Seite][, sichtbare_Seite]
Typ: Anweisung
Kategorie: Grafik

SCREENSET setzt die aktive und die sichtbare Bildschirmseite.

SCREENSET ermöglicht es Ihnen, die Nummer der aktuellen aktiven und sichtbaren Bildschirmseite zu bestimmen.
Sie können SCREENSET benutzen, um "page-flipping" oder "double-buffering" zu ermöglichen.

Beispiel:

' Bildschirmmodus 320x200x8bpp mit 2 Seiten setzen
' Hintergrundfarbe auf weiß setzen
SCREENRES 320, 200, ,2
COLOR ,15

DIM x AS INTEGER
x = -40

' eine Seite anzeigen, während die andere bearbeitet wird
SCREENSET 1, 0

DO
   CLS
   LINE (x, 80)-(x + 39, 119), 4, BF
   x += 1
   IF (x > 319) THEN x = -40
   ' warte auf Bildschirmaktualisierung
   SCREENSYNC
   ' aktive Seite auf sichtbare kopieren
   SCREENCOPY
LOOP WHILE INKEY = ""

Unterschiede zu QB: neu in FreeBASIC

Unterschiede unter den FB-Dialektformen:
In der Dialektform -lang qb steht SCREENSET nicht zur Verfügung und kann nur über __SCREENSET aufgerufen werden.

Siehe auch:
SCREENRES, SCREENCOPY, SCREENSYNC, Grafik